Какой из десяти массивов имеет максимальную сумму элементов?

Тема: 
Функции

Среди ряда одноразмерных массивов найти тот, сумма элементов которого максимальна. Вывести на экран все массивы, но сохранить в памяти только найденный массив. Также вывести на экран максимальную сумму, и номер найденного массива.

При решении данной задачи надо использовать функцию, т.к. в программе десять раз будут выполняться однотипные операции - заполнение массива, подсчет суммы его элементов и вывод на экран. Все эти операции можно поместить в одну функцию и вызывать ее десять раз из основного алгоритма. Пусть эта функция возвращает найденную сумму, а заполняет массив, переменная которого будет глобальной. Это позволит обращаться к этой переменной как из функции, так и из основного алгоритма.

В основном алгоритме нам потребуются переменные для хранения максимальной суммы, соответствующего ей массива, его последовательного номера в ряде сгенерированных массивов. Также два счетчика и переменная для суммы элементов текущего массива.

Кратко алгоритм решения данной задачи можно описать следующим образом. Десять раз вызывать функцию. Возвращаемое ей значение присваивать переменной. Если значение этой переменной больше, чем то что хранится в переменной "сумма", то сохранять массив, связанный с глобальной переменной в локальную переменную, перезаписывать значения переменных "сумма" и "индекс".

цел Н = 7
цел таб а[1:Н]
алг 
нач
  цел сч, сч2, индекс, сумма, сумма_текущая
  цел таб б[1:Н]
  сумма := 0
  индекс := 1
  нц для сч от 1 до 10
    сумма_текущая := массив
    если сумма < сумма_текущая то
      сумма := сумма_текущая
      индекс := сч
      нц для сч2 от 1 до Н
        б[сч2] := а[сч2]
      кц
    все
  кц
  вывод индекс, нс
  вывод сумма
кон
 
алг цел массив
нач
  цел сч
  знач := 0
  нц для сч от 1 до Н
    а[сч] := int(rand(0,50))
    вывод а[сч], " "
    знач := знач + а[сч]
  кц
  вывод " - ", знач, нс
кон

Пример выполнения программы

15 6 4 0 46 13 10  - 94
20 21 44 23 46 4 47  - 205
48 35 32 19 6 29 43  - 212
22 3 0 30 27 37 29  - 148
27 23 13 41 43 7 31  - 185
17 7 15 45 41 44 48  - 217
4 32 32 1 4 41 26  - 140
5 34 21 39 40 32 9  - 180
13 20 42 24 34 22 32  - 187
7 5 0 13 27 47 1  - 100
6
217